Ledendm2行会发钱系统传奇脚本

[@Mir2m2行会发钱脚本QM]
{
#IF
CHECKLEVELEX > 0
#ACT
VAR Integer HUMAN 行会发钱时长
VAR String  HUMAN 行会发钱会名
LOADVAR HUMAN 行会发钱会名 ..\QuestDiary\Mir2m2开区清空文本(免费脚本群.347979)\Mir2m2行会发钱个人.txt
LOADVAR HUMAN 行会发钱时长 ..\QuestDiary\Mir2m2开区清空文本(免费脚本群.347979)\Mir2m2行会发钱个人.txt

[@Mir2m2行会发钱弹窗]
#IF
HAVEGUILD
#ELSEACT
BREAK
#IF
CHECKVAR GLOBAL 行会发钱检测 = <$GUILDNAME>
#ACT
DELAYGOTO 1 @Mir2m2行会发钱脚本NPC

[@Mir2m2行会发钱脚本NPC]
#IF
HAVEGUILD
#ELSEACT
MESSAGEBOX 对不起，你并没有加入行会！
BREAK

#IF
HAVEGUILD
#ACT
GOTO @Mir2m2行会发钱申明
MOV S10 <$GUILDNAME>
MOV S11 <$GUILD(行会发钱库存)>
MOV S12 <$GUILD(行会发钱数量)>
MOV S13 <$GUILD(行会发钱等级)>
#ELSEACT
MOV S10 未加入行会
MOV S11
MOV S12
MOV S13
#IF
CHECKLEVELEX > 0
#ACT
MOV S14 <COLOR=clRed
INC S14
INC S14 未开启>
MOV S15 →　<开启领钱/@Mir2m2行会发钱开启>
#IF
HAVEGUILD
CHECKVAR GUILD 行会发钱开启 = 1
#ACT
MOV S14 <COLOR=clLime
INC S14
INC S14 已开启>
MOV S15 →　<关闭领钱/@Mir2m2行会发钱开启>

#IF
ISGUILDMASTER
#SAY
<COLOR=clFuchsia 您的行会名称：><$STR(S10)>\
<COLOR=clFuchsia 当前库存数量：><$STR(S11)>\
<COLOR=clFuchsia 每人可领数量：><$STR(S12)>\
<COLOR=clFuchsia 领取需要等级：><$STR(S13)>\
<COLOR=clFuchsia 领取开启状态：><$STR(S14)>  <$STR(S15)>\
\ \
<存入货币/@Mir2m2行会发钱存入>  <取回货币/@Mir2m2行会发钱取回>  <设置每人可领数量/@Mir2m2行会发钱数量>  <设置领取需要等级/@Mir2m2行会发钱等级>\
\ \
<行会成员点此领取/@Mir2m2行会发钱领取>　　<查看已领取记录名单/@Mir2m2行会发钱名单>\

#ELSESAY
<COLOR=clFuchsia 您的行会名称：><$STR(S10)>\
<COLOR=clFuchsia 当前库存数量：><$STR(S11)>\
<COLOR=clFuchsia 每人可领数量：><$STR(S12)>\
<COLOR=clFuchsia 领取需要等级：><$STR(S13)>\
<COLOR=clFuchsia 领取开启状态：><$STR(S14)>\
\ \
<存入货币/@Mir2m2行会发钱存入>   \
\ \
<行会成员点此领取/@Mir2m2行会发钱领取>　　<查看已领取记录名单/@Mir2m2行会发钱名单>\


[@Mir2m2行会发钱取回]
#ACT
QUERYVALUE 90 1 9 @Mir2m2行会发钱取回2 请输入您要取回的数量： QM
[@Mir2m2行会发钱取回2]
#IF
HAVEGUILD
#ACT
GOTO @Mir2m2行会发钱申明
#ELSEACT
MESSAGEBOX 对不起，你并没有加入行会！
BREAK
#IF
ISGUILDMASTER
#ELSEACT
MESSAGEBOX 对不起，您并非行会掌门人，无法领回！
break
#IF
LARGE M90 0
#ELSEACT
MESSAGEBOX 对不起，请输入大于0的整数！
BREAK
#IF
CHECKVAR GUILD 行会发钱库存 < <$STR(M90)>
#ACT
MESSAGEBOX 对不起，当前库存数量不足【<$STR(M90)>】！
GOTO @Mir2m2行会发钱脚本NPC
BREAK
#IF
CHECKLEVELEX > 0
#ACT
GAMEGIRD + <$STR(M90)>
CALCVAR GUILD 行会发钱库存 - <$STR(M90)>
SAVEVAR GUILD 行会发钱库存 ..\QuestDiary\Mir2m2开区清空文本(免费脚本群.347979)\Mir2m2行会发钱变量.txt
SENDMSG 8 行会老大【<$USERNAME>】取回【<$STR(M90)>】，当前库存为【<$GUILD(行会发钱库存)>】！
GOTO @Mir2m2行会发钱脚本NPC

[@Mir2m2行会发钱存入]
#ACT
QUERYVALUE 90 1 9 @Mir2m2行会发钱存入2 请输入您要存入的数量：单次最低【$(行会发钱最低存入)】 QM
[@Mir2m2行会发钱存入2]
#IF
HAVEGUILD
#ACT
GOTO @Mir2m2行会发钱申明
#ELSEACT
MESSAGEBOX 对不起，你并没有加入行会！
BREAK
#IF
SMALL M90 $(行会发钱最低存入)
#ACT
MESSAGEBOX 对不起，单次存入不得低于【$(行会发钱最低存入)】，请重新输入！
BREAK
#IF
CHECKGAMEGIRD < <$STR(M90)>
#ACT
MESSAGEBOX 对不起，您身上的货币不足【<$STR(M90)>】，请重新输入！
BREAK
#IF
CHECKLEVELEX > 0
#ACT
GAMEGIRD - <$STR(M90)>
CALCVAR GUILD 行会发钱库存 + <$STR(M90)>
SAVEVAR GUILD 行会发钱库存 ..\QuestDiary\Mir2m2开区清空文本(免费脚本群.347979)\Mir2m2行会发钱变量.txt
GOTO @Mir2m2行会发钱脚本NPC
#IF
ISGUILDMASTER
#ACT
SENDMSG 8 行会老大【<$USERNAME>】存入【<$STR(M90)>】，当前库存为【<$GUILD(行会发钱库存)>】！
#ELSEACT
SENDMSG 8 行会成员【<$USERNAME>】存入【<$STR(M90)>】，当前库存为【<$GUILD(行会发钱库存)>】！

[@Mir2m2行会发钱数量]
#ACT
QUERYVALUE 90 1 9 @Mir2m2行会发钱数量2 请输入每人可领取的数量：【$(行会发钱最低发钱)】—【$(行会发钱最高发钱)】 QM
[@Mir2m2行会发钱数量2]
#IF
HAVEGUILD
#ACT
GOTO @Mir2m2行会发钱申明
#ELSEACT
MESSAGEBOX 对不起，你并没有加入行会！
BREAK
#IF
ISGUILDMASTER
#ELSEACT
MESSAGEBOX 对不起，您并非行会掌门人，无法设置！
break
#IF
SMALL M90 $(行会发钱最低发钱)
#ACT
MESSAGEBOX 对不起，每人发钱数量不得低于【$(行会发钱最低发钱)】，请重新输入！
BREAK
#IF
LARGE M90 $(行会发钱最高发钱)
#ACT
MESSAGEBOX 对不起，每人发钱数量不得高于【$(行会发钱最高发钱)】，请重新输入！
BREAK
#IF
CHECKLEVELEX > 0
#ACT
CALCVAR GUILD 行会发钱数量 = <$STR(M90)>
SAVEVAR GUILD 行会发钱数量 ..\QuestDiary\Mir2m2开区清空文本(免费脚本群.347979)\Mir2m2行会发钱变量.txt
SENDMSG 6 每人发钱数量已设置为：<$STR(M90)>
GOTO @Mir2m2行会发钱脚本NPC

[@Mir2m2行会发钱等级]
#ACT
QUERYVALUE 90 1 9 @Mir2m2行会发钱等级2 请输入每人领取需要的等级： QM
[@Mir2m2行会发钱等级2]
#IF
HAVEGUILD
#ACT
GOTO @Mir2m2行会发钱申明
#ELSEACT
MESSAGEBOX 对不起，你并没有加入行会！
BREAK
#IF
ISGUILDMASTER
#ELSEACT
MESSAGEBOX 对不起，您并非行会掌门人，无法设置！
break
#IF
LARGE M90 0
#ELSEACT
MESSAGEBOX 对不起，请输入大于0的整数！
BREAK
#IF
CHECKLEVELEX > 0
#ACT
CALCVAR GUILD 行会发钱等级 = <$STR(M90)>
SAVEVAR GUILD 行会发钱等级 ..\QuestDiary\Mir2m2开区清空文本(免费脚本群.347979)\Mir2m2行会发钱变量.txt
SENDMSG 6 每人领取需要等级已设置为：<$STR(M90)>
GOTO @Mir2m2行会发钱脚本NPC

[@Mir2m2行会发钱名单]
#IF
HAVEGUILD
#ACT
GOTO @Mir2m2行会发钱申明
#ELSEACT
MESSAGEBOX 对不起，你并没有加入行会！
BREAK

#IF
CHECKLEVELEX > 0
#SAY
<返回/@Mir2m2行会发钱脚本NPC>  <清空领取名单/@Mir2m2行会发钱清除>  <COLOR=$00B317E3 已领取的名单如下：已领取的需清空记录才能再次领取> <$GUILD(行会发钱人数)>人\
<$GUILD(行会发钱名单)>

[@Mir2m2行会发钱申明]
#IF
HAVEGUILD
#ELSEACT
BREAK
#IF
CHECKGUILDLIST ..\QuestDiary\Mir2m2开区清空文本(免费脚本群.347979)\Mir2m2行会发钱申明.txt
#ELSEACT
ADDGUILDLIST ..\QuestDiary\Mir2m2开区清空文本(免费脚本群.347979)\Mir2m2行会发钱申明.txt
VAR INTEGER GUILD 行会发钱开启
VAR INTEGER GUILD 行会发钱等级
VAR INTEGER GUILD 行会发钱数量
VAR INTEGER GUILD 行会发钱库存
VAR INTEGER GUILD 行会发钱计数
VAR INTEGER GUILD 行会发钱人数
VAR INTEGER GUILD 行会发钱时间
VAR INTEGER GUILD 行会发钱计时
VAR STRING  GUILD 行会发钱名单
LOADVAR GUILD 行会发钱开启 ..\QuestDiary\Mir2m2开区清空文本(免费脚本群.347979)\Mir2m2行会发钱变量.txt
LOADVAR GUILD 行会发钱等级 ..\QuestDiary\Mir2m2开区清空文本(免费脚本群.347979)\Mir2m2行会发钱变量.txt
LOADVAR GUILD 行会发钱数量 ..\QuestDiary\Mir2m2开区清空文本(免费脚本群.347979)\Mir2m2行会发钱变量.txt
LOADVAR GUILD 行会发钱库存 ..\QuestDiary\Mir2m2开区清空文本(免费脚本群.347979)\Mir2m2行会发钱变量.txt
LOADVAR GUILD 行会发钱计数 ..\QuestDiary\Mir2m2开区清空文本(免费脚本群.347979)\Mir2m2行会发钱变量.txt
LOADVAR GUILD 行会发钱人数 ..\QuestDiary\Mir2m2开区清空文本(免费脚本群.347979)\Mir2m2行会发钱变量.txt
LOADVAR GUILD 行会发钱时间 ..\QuestDiary\Mir2m2开区清空文本(免费脚本群.347979)\Mir2m2行会发钱变量.txt
LOADVAR GUILD 行会发钱计时 ..\QuestDiary\Mir2m2开区清空文本(免费脚本群.347979)\Mir2m2行会发钱变量.txt
LOADVAR GUILD 行会发钱名单 ..\QuestDiary\Mir2m2开区清空文本(免费脚本群.347979)\Mir2m2行会发钱变量.txt

[@Mir2m2行会发钱开启]
#IF
HAVEGUILD
#ACT
GOTO @Mir2m2行会发钱申明
#ELSEACT
MESSAGEBOX 对不起，你并没有加入行会！
BREAK
#IF
ISGUILDMASTER
#ELSEACT
MESSAGEBOX 对不起，您并非行会掌门人，无法设置！
break
#IF
CHECKVAR GUILD 行会发钱开启 = 1
#ACT
CALCVAR GUILD 行会发钱开启 = 0
SAVEVAR GUILD 行会发钱开启 ..\QuestDiary\Mir2m2开区清空文本(免费脚本群.347979)\Mir2m2行会发钱变量.txt
messagebox 您已关闭发钱，当前库存不可领取！
GOTO @Mir2m2行会发钱脚本NPC
BREAK
#IF
CHECKVAR GUILD 行会发钱数量 < $(行会发钱最低发钱)
#ACT
MESSAGEBOX 对不起，每人发钱数量不得低于【$(行会发钱最低发钱)】，请重新设置！
BREAK
#IF
CHECKVAR GUILD 行会发钱数量 > $(行会发钱最高发钱)
#ACT
MESSAGEBOX 对不起，每人发钱数量不得高于【$(行会发钱最高发钱)】，请重新设置！
BREAK
#IF
CHECKVAR GUILD 行会发钱库存 < <$GUILD(行会发钱数量)>
#ACT
messagebox 对不起，行会库存剩余为【<$GUILD(行会发钱库存)>】，无法发钱，请先存入！
BREAK
#IF
CHECKLEVELEX > 0
#ACT
MOV D9 <$GUILD(行会发钱计时)>
INC D9 $(行会发钱开启间隔)
#IF
LARGE D9 <$GLOBAL(行会发钱总时)>
#ACT
DEC D9 <$GLOBAL(行会发钱总时)>
messagebox 对不起，【<$STR(D9)>】秒后才可以再次开启！
BREAK
#IF
CHECKLEVELEX > 0
#ACT
CALCVAR GUILD 行会发钱开启 = 1
CALCVAR GUILD 行会发钱计时 = <$GLOBAL(行会发钱总时)>
SAVEVAR GUILD 行会发钱开启 ..\QuestDiary\Mir2m2开区清空文本(免费脚本群.347979)\Mir2m2行会发钱变量.txt
SAVEVAR GUILD 行会发钱计时 ..\QuestDiary\Mir2m2开区清空文本(免费脚本群.347979)\Mir2m2行会发钱计时.txt
SENDMSG 8 行会老大【<$USERNAME>】开启了发钱！库存【<$GUILD(行会发钱库存)>】，每人可领取【<$GUILD(行会发钱数量)>】！
CALCVAR GLOBAL 行会发钱检测 = <$GUILDNAME>
;GMEXECUTE 开始提问 @Mir2m2行会发钱弹窗
GOTO @Mir2m2行会发钱脚本NPC

[@Mir2m2行会发钱清除]
#IF
HAVEGUILD
#ACT
GOTO @Mir2m2行会发钱申明
#ELSEACT
MESSAGEBOX 对不起，你并没有加入行会！
BREAK
#IF
ISGUILDMASTER
#ELSEACT
MESSAGEBOX 对不起，您并非行会掌门人，无法设置！
break

#IF
CHECKLEVELEX > 0
#ACT
MOV S11 <$DATETIME>
DEC S11 5 100
MOV S10 <$DATETIME>
DEC S10 1 7
DEC S10 3 100
MOV S12 <$DATETIME>
DEC S12 1 6
MOV S13 <$DATETIME>
MOV S14 <$DATETIME>
#IF
EQUAL S10 月
#ACT
DEC S12 2 100
DEC S13 1 9
#ELSEACT
DEC S12 3 100
DEC S13 1 10
DEC S14 1 1
#IF
CHECKLEVELEX > 0
#ACT
MOV S10 <$STR(S13)>
DEC S10 4 100
DEC S10 1 1
#IF
EQUAL S10 日
#ACT
DEC S13 2 100
#ELSEACT
DEC S13 3 100
DEC S14 1 1
#IF
CHECKLEVELEX > 0
#ACT
DEC S14 1 20
MOV S15 <$STR(S14)>
DEC S14 3 100
DEC S15 1 3
DEC S15 3 100
DEC S11 1 2

MOV S10 <$STR(S11)>
#IF
CHECKLEVELEX > 0
#ACT
MOV D9 <$STR(S12)>
#IF
SMALL D9 10
#ACT
INC S10 0
INC S10 <$STR(D9)>
#ELSEACT
INC S10 <$STR(D9)>
#IF
CHECKLEVELEX > 0
#ACT
MOV D9 <$STR(S13)>
#IF
SMALL D9 10
#ACT
INC S10 0
INC S10 <$STR(D9)>
#ELSEACT
INC S10 <$STR(D9)>
#IF
CHECKLEVELEX > 0
#ACT
MOV D9 <$STR(S14)>
#IF
SMALL D9 10
#ACT
INC S10 0
INC S10 <$STR(D9)>
#ELSEACT
INC S10 <$STR(D9)>
#IF
CHECKLEVELEX > 0
#ACT
MOV D9 <$STR(S15)>
#IF
SMALL D9 10
#ACT
INC S10 0
INC S10 <$STR(D9)>
#ELSEACT
INC S10 <$STR(D9)>

#IF
CHECKLEVELEX > 0
#ACT
MOV D9 <$STR(S10)>
#IF
LARGE D9 <$GUILD(行会发钱时间)>
#ACT
MOV D8 0
#ELSEACT
MOV D8 1
MOV D7 <$GUILD(行会发钱时间)>
DEC D7 <$STR(D9)>
#IF
EQUAL D8 1
EQUAL D7 0
#ACT
INC D7 1
#IF
EQUAL D8 1
#ACT
MESSAGEBOX 对不起，请<$STR(D7)>分钟后再清理！
BREAK

#IF
CHECKVAR GUILD 行会发钱名单 =
#ELSEACT
SENDMSG 8 行会老大【<$USERNAME>】清理了领取记录，已领取过的可重新领取！
#IF
CHECKLEVELEX > 0
#ACT
CALCVAR GUILD 行会发钱名单 =
CALCVAR GUILD 行会发钱时间 = <$STR(D9)>
CALCVAR GUILD 行会发钱人数 = 0
SAVEVAR GUILD 行会发钱人数 ..\QuestDiary\Mir2m2开区清空文本(免费脚本群.347979)\Mir2m2行会发钱变量.txt
SAVEVAR GUILD 行会发钱时间 ..\QuestDiary\Mir2m2开区清空文本(免费脚本群.347979)\Mir2m2行会发钱变量.txt
SAVEVAR GUILD 行会发钱名单 ..\QuestDiary\Mir2m2开区清空文本(免费脚本群.347979)\Mir2m2行会发钱变量.txt
MESSAGEBOX 清理成功，所有行会成员的领取记录已清空！
GOTO @Mir2m2行会发钱名单

[@Mir2m2行会发钱领取]
#IF
HAVEGUILD
#ACT
GOTO @Mir2m2行会发钱申明
#ELSEACT
MESSAGEBOX 对不起，你并没有加入行会！
BREAK

#IF
CHECKVAR GUILD 行会发钱开启 = 1
#ELSEACT
messagebox 对不起，行会老大还未开启发钱！
GOTO @Mir2m2行会发钱脚本NPC
BREAK
#IF
CHECKLEVELEX < <$GUILD(行会发钱等级)>
#ACT
messagebox 对不起，你的等级未达到<$GUILD(行会发钱等级)>级，无法领取！
GOTO @Mir2m2行会发钱脚本NPC
BREAK
#IF
CHECKVAR GUILD 行会发钱库存 < <$GUILD(行会发钱数量)>
#ACT
messagebox 对不起，行会库存剩余为【<$GUILD(行会发钱库存)>】，无法领取，请联系行会老大存入！
GOTO @Mir2m2行会发钱脚本NPC
BREAK
#IF
CHECKVAR GUILD 行会发钱数量 > 0
#ELSEACT
MESSAGEBOX 对不起，当前发钱数量为【0】，无法领取！
GOTO @Mir2m2行会发钱脚本NPC
BREAK
#IF
CHECKVAR HUMAN 行会发钱会名 = <$GUILDNAME>
CHECKVAR HUMAN 行会发钱时长 ? <$GUILD(行会发钱时间)>
#ACT
MESSAGEBOX 对不起，本次发钱你已领取过，行会老大清空领取记录才能再次领取！
BREAK
#IF
CHECKLEVELEX > 0
#ACT
GAMEGIRD + <$GUILD(行会发钱数量)>
CALCVAR GUILD 行会发钱库存 - <$GUILD(行会发钱数量)>
CALCVAR GUILD 行会发钱人数 + 1
CALCVAR GUILD 行会发钱计数 + 1
MOV S10 <$USERNAME><$GLOBAL(行会发钱空格)>
DEC S10 16 500
INC S10 <$GUILD(行会发钱名单)>
CALCVAR GUILD 行会发钱名单 = <$STR(S10)>
SAVEVAR GUILD 行会发钱人数 ..\QuestDiary\Mir2m2开区清空文本(免费脚本群.347979)\Mir2m2行会发钱变量.txt
SAVEVAR GUILD 行会发钱库存 ..\QuestDiary\Mir2m2开区清空文本(免费脚本群.347979)\Mir2m2行会发钱变量.txt
CALCVAR HUMAN 行会发钱会名 = <$GUILDNAME>
CALCVAR HUMAN 行会发钱时长 = <$GUILD(行会发钱时间)>
SAVEVAR HUMAN 行会发钱会名 ..\QuestDiary\Mir2m2开区清空文本(免费脚本群.347979)\Mir2m2行会发钱个人.txt
SAVEVAR HUMAN 行会发钱时长 ..\QuestDiary\Mir2m2开区清空文本(免费脚本群.347979)\Mir2m2行会发钱个人.txt
#IF
CHECKVAR GUILD 行会发钱计数 < $(行会发钱每行人名)
#ELSEACT
MOV S10 \<$GUILD(行会发钱名单)>
CALCVAR GUILD 行会发钱名单 = <$STR(S10)>
CALCVAR GUILD 行会发钱计数 = 0
#IF
CHECKLEVELEX > 0
#ACT
SAVEVAR GUILD 行会发钱计数 ..\QuestDiary\Mir2m2开区清空文本(免费脚本群.347979)\Mir2m2行会发钱变量.txt
SAVEVAR GUILD 行会发钱名单 ..\QuestDiary\Mir2m2开区清空文本(免费脚本群.347979)\Mir2m2行会发钱变量.txt
SENDMSG 8 【<$USERNAME>】领取了<$GUILD(行会发钱数量)>货币，领取人数[<$GUILD(行会发钱人数)>]人，库存剩余[<$GUILD(行会发钱库存)>]
close

[@Mir2m2行会发钱常量加载]
#CALL [\Mir2m2行会发钱配置(免费脚本群.347979)\Mir2m2行会发钱常量.ini] @Mir2m2行会发钱常量
}

[@Mir2m2行会发钱脚本RM]
{
#IF
SMALL I66 347979
#ACT
MOV I66 347979
VAR String  GLOBAL 行会发钱检测
VAR Integer GLOBAL 行会发钱总时
VAR String  GLOBAL 行会发钱空格
LOADVAR GLOBAL 行会发钱空格 ..\QuestDiary\Mir2m2行会发钱配置(免费脚本群.347979)\Mir2m2行会发钱常量.ini
MOV S10 <$GLOBAL(行会发钱空格)>
DEC S10 1 1
CALCVAR GLOBAL 行会发钱空格 = <$STR(S10)>
CLEARNAMELIST ..\QuestDiary\Mir2m2开区清空文本(免费脚本群.347979)\Mir2m2行会发钱申明.txt
CLEARNAMELIST ..\QuestDiary\Mir2m2开区清空文本(免费脚本群.347979)\Mir2m2行会发钱计时.txt
#ELSEACT
CALCVAR GLOBAL 行会发钱总时 + 2
}



注册会员回复下载：

游客，如果您要查看本帖隐藏内容请回复

传奇服务端传奇服务端传奇服务端

这个复杂啊

123156456456465